Lengthy Start-Up Screens
» > >
»
» View previous topic :: View next topic  
I just finished Phoenix basic today, and I had a cool idea for a start-up screen when you run the program.

I still don't know how to get animated screen shots for an 84+SE, so I can only give stills, but they wouldn't help.

The ship you use shoots "PHOENIX" onto the top of the screen and then it displays the other stuff ("copyright" date - or when I started, my name, version), and finally, it has a fade in affect for "Penguin Studios." The fade in affect takes a while on my 84+SE, so I have no idea how long it would take on an 83+, or if it would even look right.

Also, on the main menu, it has a custom selecter (don't know the right word, its > and the bold right arrow, flashing) and flashes PHOENIX at the top of the screen, and it has a ship moving randomly around the screen.
Would something like this be too much for an 83+ to handle (and still look good)?

I can email anyone the program, or you can wait until the beta arrives in ticalc.orgs archives.

Thanks for any help!
Penguin Studios
Well, that sounds like it could work, although it might be a lot of work. The title screen wouldn't be too hard, although it would take several hundred bytes at least, and you could pretty easily control effects with interrupts on the main menu.
タリ ·· Ask questions the smart way ·· digipres.club
I already added it - it wasn't too hard (only took about 10 minutes).

Here is the source code:


Code:
:ClrHome
:"PHOENIX→Str1
:For(I,2,14,2
:¦ Output(8,I-1,"  Δ
:¦ For(J,7,1,‾1
:¦ ¦ Output(J,I,sub(Str1,I/2,1
:¦ ¦ If J<7:Output(J+1,I,"
:¦ End
:End
:Output(8,15,"
:Output(2,7,"v1.0
:Output(3,2,"(C) 11/10/2006
:rand(50
:Output(7,7,"By:
:Output(8,3,"Bryce Taylor
:For(J,1,11
:¦ For(K,1,4
:¦ ¦ Output(5,1,"Penguin Studios
:¦ ¦ For(I,J,10
:¦ ¦ ¦ Output(5,1,"               
:¦ ¦ End
:¦ End
:End
:Pause
:DelVar M
:Repeat M
:¦ ClrHome
:¦ Disp ""," Start"," High Scores"," Exit
:¦ Output(8,1,"[DEL]-High Score
:¦ DelVar θ2→Q
:¦ 8→R
:¦ Repeat max(θ=105,21
:¦ ¦ getKey→θ
:¦ ¦ Output(Q,1,">
:¦ ¦ Q+(θ=34 and Q<4)-(θ=25 and Q>2→Q
:¦ ¦ R+randInt(‾(R>1),(R<14→R
:¦ ¦ Output(6,R," Δ
:¦ ¦ Output(1,5,"       
:¦ ¦ Output(Q,1,"
:¦ ¦ If θ
:¦ ¦ Then
:¦ ¦ ¦ Output(Q-1,1,"
:¦ ¦ ¦ Output(Q+1,1,"
:¦ ¦ End
:¦ ¦ If θ=23
:¦ ¦ Then
:¦ ¦ ¦ ClrList∟PX
:¦ ¦ ¦ Output(7,4,"Cleared!
:¦ ¦ ¦ rand(85
:¦ ¦ ¦ Output(7,4,"       
:¦ ¦ End
:¦ ¦ Output(1,5,"PHOENIX
:¦ End
:¦ DelVar LDelVar S5→W
:¦ SetUpEditor∟PX
:¦ 29→dim(∟PX
:¦ If not(∟PX(29
:¦ 1024,512,256,128,64,32,16,2,23,20,16,28,19,3,29,19,28,28,28,16,5,14,7,21,9,14,28,28,9→∟PX
:¦ If Q=4
:¦ 2→M
:¦ If Q=2
:¦ Then
:¦ ¦ Repeat not(W
:¦ ¦ ¦ 1+L→L
:¦ ¦ ¦ 4→B:9→C:2→F:2→H:L→U:L→V
:¦ ¦ ¦ ClrHome
:¦ ¦ ¦ 8→X
:¦ ¦ ¦ Output(8,8,"Δ
:¦ ¦ ¦ Repeat not(W) or (not(U) and not(V
:¦ ¦ ¦ ¦ getKey→θ
:¦ ¦ ¦ ¦ F+(E>0→F
:¦ ¦ ¦ ¦ H+(G>0→H
:¦ ¦ ¦ ¦ If F>8
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ 2→F
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If H>8
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ 2→H
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ randInt(0,1→D
:¦ ¦ ¦ ¦ If not(D
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ If V
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ Output(1,B,"
:¦ ¦ ¦ ¦ ¦ ¦ B+randInt(‾(B>1),(B<16→B
:¦ ¦ ¦ ¦ ¦ ¦ Output(1,B,"Δ
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ If U
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ Output(1,C,"
:¦ ¦ ¦ ¦ ¦ ¦ C+randInt(‾(C>1),(C<16→C
:¦ ¦ ¦ ¦ ¦ ¦ Output(1,C,"Δ
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If D
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ If F=2
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ randInt(0,1→E
:¦ ¦ ¦ ¦ ¦ ¦ If Ans
:¦ ¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ ¦ C→E
:¦ ¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ If H=2
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ randInt(0,1→G
:¦ ¦ ¦ ¦ ¦ ¦ If Ans
:¦ ¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ ¦ B→G
:¦ ¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If E and U
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ Output(F-(F≠2),E,"
:¦ ¦ ¦ ¦ ¦ Output(F,E,"γ
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If G and V
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ Output(H-(H≠2),G,"
:¦ ¦ ¦ ¦ ¦ Output(H,G,"γ
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If max(θ=24,25,26,34
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ If θ=45
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ DelVar W
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ Output(8,X,"
:¦ ¦ ¦ ¦ ¦ X+(θ=26 and X<16)-(θ=24 and X>1→X
:¦ ¦ ¦ ¦ ¦ Output(8,X,"Δ
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If θ=21
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ S-2→S
:¦ ¦ ¦ ¦ ¦ For(A,1,7
:¦ ¦ ¦ ¦ ¦ ¦ Output(8-A,X,":
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ For(A,1,7
:¦ ¦ ¦ ¦ ¦ ¦ Output(8-A,X,"
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ If X=B
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ S+(V>0)randInt(1,25-V→S
:¦ ¦ ¦ ¦ ¦ ¦ V-(V>0→V
:¦ ¦ ¦ ¦ ¦ ¦ If G and not(V
:¦ ¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ ¦ Output(H,G,"
:¦ ¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ If X=C
:¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ S+(U>0)randInt(1,25-U→S
:¦ ¦ ¦ ¦ ¦ ¦ U-(U>0→U
:¦ ¦ ¦ ¦ ¦ ¦ If E and not(U
:¦ ¦ ¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ ¦ ¦ Output(F,E,"
:¦ ¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If H=8
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ W-(G=X→W
:¦ ¦ ¦ ¦ ¦ Output(8,G,"
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ If F=8
:¦ ¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ ¦ W-(E=X→W
:¦ ¦ ¦ ¦ ¦ Output(8,E,"
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ End
:¦ ¦ ¦ ClrHome
:¦ ¦ ¦ Disp "Next Level!","Score:","Life:
:¦ ¦ ¦ Output(2,8,S
:¦ ¦ ¦ Output(3,6,sub(" ΔΔΔΔΔ",1,W+1
:¦ ¦ ¦ Pause
:¦ ¦ ¦ ClrHome
:¦ ¦ End
:¦ End
:¦ If Q≠4
:¦ Then
:¦ ¦ ClrHome
:¦ ¦ DelVar J
:¦ ¦ For(I,7,2,‾1
:¦ ¦ ¦ If S>∟PX(I) and S≤∟PX(I-1
:¦ ¦ ¦ Then
:¦ ¦ ¦ ¦ For(K,6,I,‾1
:¦ ¦ ¦ ¦ ¦ ∟PX(K→∟PX(K+1
:¦ ¦ ¦ ¦ ¦ ∟PX(29-3K→∟PX(26-3K
:¦ ¦ ¦ ¦ ¦ ∟PX(30-3K→∟PX(27-3K
:¦ ¦ ¦ ¦ ¦ ∟PX(31-3K→∟PX(28-3K
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ I→J
:¦ ¦ ¦ ¦ S→∟PX(I
:¦ ¦ ¦ End
:¦ ¦ End
:¦ ¦ If S>∟PX(1
:¦ ¦ Then
:¦ ¦ ¦ For(I,6,1,‾1
:¦ ¦ ¦ ¦ ∟PX(I→∟PX(I+1
:¦ ¦ ¦ ¦ ∟PX(29-3I→∟PX(26-3I
:¦ ¦ ¦ ¦ ∟PX(30-3I→∟PX(27-3I
:¦ ¦ ¦ ¦ ∟PX(31-3I→∟PX(28-3I
:¦ ¦ ¦ End
:¦ ¦ ¦ S→∟PX(1
:¦ ¦ ¦ 1→J
:¦ ¦ End
:¦ ¦ DelVar θ1→A
:¦ ¦ If J
:¦ ¦ Then
:¦ ¦ ¦ Disp "High Score!
:¦ ¦ ¦ For(I,1,3
:¦ ¦ ¦ ¦ Repeat θ=105
:¦ ¦ ¦ ¦ ¦ getKey→θ
:¦ ¦ ¦ ¦ ¦ A+(θ=34 and A<55)-(θ=25 and A>1→A
:¦ ¦ ¦ ¦ ¦ Output(4,5+I,sub("ABCDEFGHIJKLMNOPQRSTUVWXYZθ .abcdefghijklmnopqrstuvwxyz",A,1
:¦ ¦ ¦ ¦ End
:¦ ¦ ¦ ¦ A→∟PX(4+3J+I
:¦ ¦ ¦ End
:¦ ¦ ¦ ClrHome
:¦ ¦ End
:¦ ¦ Disp "  High Scores:
:¦ ¦ For(I,7,1,‾1
:¦ ¦ ¦ For(K,1,3
:¦ ¦ ¦ ¦ Output(I+1,K,sub("ABCDEFGHIJKLMNOPQRSTUVWXYZθ .abcdefghijklmnopqrstuvwxyz",∟PX(3I+K+4),1
:¦ ¦ ¦ End
:¦ ¦ ¦ Output(I+1,4,":
:¦ ¦ ¦ Output(I+1,5,∟PX(I
:¦ ¦ End
:¦ ¦ Pause
:¦ ¦ ClrHome
:¦ End
:End
:ClrHome
:Archive∟PX
:Disp "Thanks for","Playing!


How does it look?
Penguin Studios
Super, except for the missing
SourceCoder 2.0 wrote:
Generated by SourceCoder, © 2005-2006 Cemetech
Ooops, forgot to copy that part.

Has anyone tested it on a regular TI-83+ yet? I really want to know about the speed...

Forgot to mention this earlier, but I think there MIGHT be a bug in the highscore part of it. I thought that I saw it mess up, but it has worked correctly ever since then, so I don't know.

Thanks again!
Penguin Studios
High scores... hmmm, that section looks fine to me, but you might want to doublecheck it before your final nonbeta release.
  
Register to Join the Conversation
Have your own thoughts to add to this or any other topic? Want to ask a question, offer a suggestion, share your own programs and projects, upload a file to the file archives, get help with calculator and computer programming, or simply chat with like-minded coders and tech and calculator enthusiasts via the site-wide AJAX SAX widget? Registration for a free Cemetech account only takes a minute.

» Go to Registration page
Lengthy Start-Up Screens
»
» View previous topic :: View next topic  
Page 1 of 1
» All times are UTC - 5 Hours
 
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum

 

Advertisement